|
| | | |
 • I.3. Access - Formularze [1] •
- 3.1 Jak przesunąć formularz bez zmiany jego rozmiaru oraz jak zmienić rozmiar formularza bez zmiany jego położenia ?
- 3.2 Dziewięć wizualnych sposobów otwarcia formularza.
- 3.3 Czy można otworzyć ten sam formularz w nowym oknie ?
- 3.4 Jak zmusić Access do korzystania z szablonów formularzy i raportów ?
- 3.5 Jak sprawdzić, czy wybrane formanty formularza zostały wypełnione ?
- 3.6 Jak pobrać nazwy wbudowanych i niestandardowych pasków poleceń oraz sprawdzić, który z nich jest widoczny ?
- 3.7 Jak sprawdzić, która sekcja formularza zawiera formant ?
- 3.8 Jak zrobić migającą etykietę na formularzu ?
- 3.9 Jak zrobić pasek postępu osadzony w formularzu, lub uruchamiany jako modalny formularz ?
- <<• idź do str. 2 •>>
| | | | |
 |
| | |
|
3.1 Jak przesunąć formularz bez zmiany jego rozmiaru oraz jak zmienić rozmiar formularza bez zmiany jego położenia ?
' należy użyć metody:
' DoCmd.MoveSize [w prawo], [w dół], [szerokość], [wysokość]
' w metodzie MoveSize trzeba podać co najmniej jeden argument, jeżeli jakiś argument pozostanie pusty, używane jest bieżące ustawienie, jednostką argumentów jest Twip,
' przykładowe wywołanie:
Private Sub btnTest_Click()
Dim i As Long
' przesuń poziomo
DoCmd.MoveSize 3000
For i = 0 To 1000: DoEvents: Next
' przesuń pionowo
DoCmd.MoveSize , 3000
For i = 0 To 1000: DoEvents: Next
' zmień rozmiar formularza (szerokość)
DoCmd.MoveSize , , 4000
For i = 0 To 1000: DoEvents: Next
' zmień wszystko
DoCmd.MoveSize 1000, 800, 7000, 5000
For i = 0 To 1000: DoEvents: Next
End Sub
ΔΔΔ | | | | |
|
|
| | |
|
3.2 Dziewięć wizualnych sposobów otwarcia formularza.
w oparciu o:
Chris St. Valentine, "Access 2.0 - Potęga programowania" wyd. LT&P wyd. 1996 r.
Przykład został trochę rozbudowany i przystosowany do 64-bitowego MS Access (VBA7).
Obecnie przykład znajduje się na stronie:
• Niekonwencjonalne otwarcie formularza. Od lewej do prawej strony strony. •
oraz
• Dziewięć wizualnych sposobów otwarcia formularza. •
ΔΔΔ | | | | |
|
|
| | |
|
3.3 Czy można otworzyć ten sam formularz w nowym oknie ?
Można, pod warunkiem, że wywołamy nową instanację formularza.
W tym celu musimy zadeklarować frmNew As Access.Form jako:
• zmienną na poziome modułu formularza:
Private frmNew As Access.Form
• lub jako zmienną Static w procedurze:
Static frmNew As Access.Form
• w przypadku deklaracji w procedurze:
Dim frmNew As Access.Form
formularz zostanie otwarty tylko na czas działania procedury.
UWAGA: formularz musi mieć ustawioną właściwość: HasModule = Yes
Private frmNew As Access.Form
' przykładowe wywołanie:
Private Sub btnTest_Click()
' utwórz pierwszą instancję formularza
DoCmd.OpenForm "frmMojFormularz"
' utwórz druga instancję formularza
Set frmNew = New Form_frmMojFormularz
With frmNew
.Visible = True
' w celach demonstracyjnych zmieniaj rozmiar formularza
.Caption = "Nowa instancja formularza"
.InsideWidth = .InsideWidth - 1000
.InsideHeight = .InsideHeight - 500
.SetFocus
End With
' i gdzieś w kodzie, by zamknąć nową instancję formularza
' Set frmNew = Nothing
End Sub
ΔΔΔ | | | | |
|
|
| | |
|
3.4 Jak zmusić Access do korzystania z szablonów formularzy i raportów ?
<cyt>
- Utwórz sobie pusty formularz
- Pozmieniaj nazwy sekcji formularza, najlepiej na: Header, Footer, Detail
- Przy okazji dostosuj standardowe właściwości formularza i sekcji formularza do logiki Twojej aplikacji (styl obramowania, selektory rekordów, paski przewijania, kolor tła, itp.)
- Zapisz formularz jako np. frmTemplate
- W menu "Narzędzia" => "Opcje" => "Formularze/Raporty" zmień wpis w polu "Szablon formularza" z "Normalny" na "frmTemplate"
- i analogicznie dla raportu.
</cyt>
ΔΔΔ | | | | |
|
|
| | |
|
3.5 Jak sprawdzić, czy wybrane formanty formularza zostały wypełnione ?
' Utwórz następujące przykładowe formanty na formularzu:
' txtImie, txtNazwisko, cboMiasto, txtZaklad.
' Jeżeli wszystkie formanty są wypełnione funkcja zwraca True, w przeciwnym wypadku wyświetlany jest komunikat, a fokus ustawiany jest na pierwszym niewypełnionym formancie (jeżeli to ComboBox to rozwijana jest lista), a funkcja zwraca False,
Private Function zbCheckCtl() As Boolean
Dim vCtl As Variant
Dim sMsg As String
Dim i As Integer
Dim j As Integer
' tablica typu Variant przykładowych formantów i odpowiadających im nazw opisowych
vCtl = Array(Me.txtImie, "Imię:", _
Me.txtNazwisko, "Nazwisko:", _
Me.cboMiasto, "Miasto:", _
Me.txtZaklad, "Nazwa zakładu:")
j = -1
For i = LBound(vCtl) To UBound(vCtl) Step 2
If Nz(vCtl(i), "") = "" Then
' zapamiętaj w zmiennej j indeks pierwszego pustego formantu
If j < 0 Then j = i
sMsg = sMsg & vbNewLine & " " & vCtl(i + 1)
End If
Next
' sprawdź, długość ciągu znaków
If Len(sMsg) > 0 Then
MsgBox "Wypełnij pole(a): " & sMsg
' ustaw fokus na pierwszym pustym formancie, jeżeli jest aktywny
If vCtl(j).Enabled = False Then Exit Function
vCtl(j).SetFocus
' jeżeli jest to ComboBox to rozwiń listę
If TypeOf vCtl(j) Is Access.ComboBox Then
vCtl(j).Dropdown
End If
Else
zbCheckCtl = True
End If
End Function
' przykładowe wywołanie:
Private Sub btnTest_Click()
If zbCheckCtl = True Then
MsgBox "Wszystkie wypełnione !"
Else
' Błąd! Funkcja zbCheckCtl wyświetli komunikat
End If
End Sub
ΔΔΔ | | | | |
|
|
| | |
|
3.6 Jak pobrać nazwy wbudowanych i niestandardowych pasków poleceń oraz sprawdzić, który z nich jest widoczny ?
Private Sub zbListCbr()
Dim cbr As Object
Dim sName As String * 34
Dim sNameLocal As String * 44
Dim sVisible As String * 12
Dim i As Integer
' przygotuj i drukuj nagłówek tabeli
sName = "|" & Space(11) & "Nazwa:"
sNameLocal = "|" & Space(9) & "Nazwa lokalna:"
sVisible = "| Widoczny:"
Debug.Print String(97, "=")
Debug.Print "| Lp. "; sName; sNameLocal; sVisible & "|"
Debug.Print String(97, "=")
' drukuj właściwą listę
For Each cbr In CommandBars
i = i + 1
sName = "| " & cbr.Name
sNameLocal = "| " & cbr.NameLocal
sVisible = "| " & cbr.Visible
Debug.Print "|" & Format(i, "000"); ". "; sName; _
sNameLocal; sVisible & "|"
Next
Debug.Print String(97, "=")
Debug.Print: Debug.Print
DoCmd.RunCommand acCmdDebugWindow
End Sub
' przykładowe zastosowanie:
grupa: pl.comp.bazy-danych.msaccess
wątek: Menu kontekstowe
ΔΔΔ | | | | |
|
|
| | |
|
3.7 Jak sprawdzić, która sekcja formularza zawiera formant ?
' Metoda I - przeszukuje kolekcję Controls każdej sekcji formularza szukając formantu sCtlName; zwraca numer jaki ma sekcja formularza w której znajduje się formant, przy niepowodzeniu zwraca -1
Private Function zbGetSectionID_1(sCtlName As String) As Long
Dim ctl As Control
Dim i As Integer
zbGetSectionID_1 = -1
For i = 0 To 2
For Each ctl In Me.Section(i).Controls
If ctl.Name = sCtlName Then
zbGetSectionID_1 = i
Exit For
End If
Next
Next
End Function
' Metoda II - sprawdzana jest każda sekcja formularza, czy znajduje się w niej nasz Obiekt, zwraca numer jaki ma sekcja formularza w której znajduje się formant, przy niepowodzeniu zwraca -1
Private Function zbGetSectionID_2(sCtlName As String) As Long
Dim arrSect(0 To 2) As Long
Dim i As Integer
' stałe Access'a: acHeader = 1; acDetail = 0; acFooter = 2
On Error Resume Next
arrSect(0) = acHeader: arrSect(1) = acDetail: arrSect(2) = acFooter
zbGetSectionID_2 = -1
For i = 0 To 2
IsObject Me.Section(arrSect(i)).Controls(sCtlName)
If Err.Number = 0 Then
zbGetSectionID_2 = arrSect(i)
Exit Function
Else
Err.Clear
End If
Next
End Function
' przykładowe wywołanie:
Private Sub btnTest_Click()
Dim lRet As Long
' lRet = zbGetSectionID_1(Screen.ActiveControl.Name)
lRet = zbGetSectionID_2(Screen.ActiveControl.Name)
If lRet > -1 Then
MsgBox "Sekcja: " & Me.Section(lRet).Name & " (" & lRet & ")"
Else
MsgBox "Niepowodzenie"
End If
End Sub
ΔΔΔ | | | | |
|
|
| | |
|
3.8 Jak zrobić migającą etykietę na formularzu ?
' utwórz etykietę o nazwie lblTest i skopiuj poniższy kod:
Private Sub Form_Load()
Me.lblTest.ForeColor = vbRed
Me.lblTest.BackColor = vbBlack
Me.TimerInterval = 1000
End Sub
Private Sub Form_Timer()
With Me.lblTest
If .ForeColor = vbRed Then
.ForeColor = vbBlack
.BackColor = vbRed
Else
.ForeColor = vbRed
.BackColor = vbBlack
End If
End With
End Sub
ΔΔΔ | | | | |
|
|
| | |
|
3.9 Jak zrobić pasek postępu osadzony w formularzu, lub uruchamiany jako modalny formularz ?
Przykład został trochę rozbudowany i przystosowany do 64-bitowego MS Access (VBA7).
Obecnie przykład znajduje się na stronie:
• Modalny pasek postępu
oraz
• Pasek postępu w formularzu
ΔΔΔ | | | | |
|
| |
